[richiesta] Programmino Asola

Moderatore: Fiveaxis

Rispondi
Avatar utente
Amrik
Newbie
Newbie
Messaggi: 42
Iscritto il: giovedì 19 ottobre 2017, 23:27
Località: cremona

[richiesta] Programmino Asola

Messaggio da Amrik » mercoledì 18 aprile 2018, 18:59

Buonasera forum,
Chiedo ancora una volta il vostro aiuto :roll: , ho iniziato a lavorare su un centro Heidenhain controllo tnc 426/430M, inizialmente usavo tnc 530, ora mi trovo in difficolta con i vari cicli sul 426.
Vorrei avere un programma jolly da poter usare per fare le asole usando un preforo, scegliendo incremento di passata in z, senza stare a modificare tutto il profilo del asola se cambia la larghezza della tale.
Vi chiedo una mano a fare un programmino con parametri Q, vi ringrazio già in anticipo!!
Immagine

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » mercoledì 18 aprile 2018, 19:38

sto facendo dei corsi in ditta a novelli operatori oltre al Selca anche in Heidenhein
..se aspetti un po in settimana (forse venerdi) abbiamo in programma anche la programmazione parametrica.
ed useremo proprio la programmazione Asola in parametrico.
..poi ti posto il programma qui...

Avatar utente
Amrik
Newbie
Newbie
Messaggi: 42
Iscritto il: giovedì 19 ottobre 2017, 23:27
Località: cremona

Re: [richiesta] Programmino Asola

Messaggio da Amrik » mercoledì 18 aprile 2018, 20:02

Certo! Ti ringrazio Gino =D>
Immagine

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » giovedì 19 aprile 2018, 13:07

@Amrik ,il programma per Asola lo abbiamo inserito in mattinata nei corsi...
i novelli hanno appreso in poco tempo il funzionamento
e` anche abbastanza semplice..lo allego con foto (anche con riferimento ai parametri utilizzati)
ci sono due versioni una con un Label di ripetizioni calcolate

Codice: Seleziona tutto

0  BEGIN PGM Parametrica-Asola MM 
1  BLK FORM 0.1 Z  X-100  Y-100  Z-40
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  FN 0: Q1 =+20 ;(mezza-Y-(Raggio Asola))
4  FN 0: Q2 =+60 ;(mezza-X-(-raggio Asola))
5  FN 0: Q3 =+38 ;(profondita-totale)
6  FN 0: Q4 =+2 ;(incremento Z(divisibile con Q3)
7  Q12 = Q3 / Q4 ;(calcolo Passate da ripetere)
8  Q12 = Q12 - 1 ;(passate meno una)
9  TOOL CALL 16 Z S1500 F200
10 ; PUNTA per PREFORO centro asola
11 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+1    ;BEZUGSPUNKT-NUMMER
12 CYCL DEF 7.0 NULLPUNKT
13 CYCL DEF 7.1  X+0
14 CYCL DEF 7.2  Y+0
15 CYCL DEF 7.3  Z+0
16 CYCL DEF 10.0 DREHUNG
17 CYCL DEF 10.1  ROT+45
18 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-45   ;TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN
19 L  X+0  Y+0  Z+5 R0 FMAX M13
20 CYCL CALL
21 L  Z+200 R0 FMAX M9
22 TOOL CALL 12 Z S5500 F1000
23 ;RICHIAMO utensile x lavorazione asola
24 L  X+0  Y+0  Z+5 R0 FMAX M13
25 L  Z+0 F AUTO
26 LBL 1
27 L IZ-Q4
28 APPR LCT  X+0  Y+Q1 R4 RL F AUTO
29 L  X-Q2
30 CR  Y-Q1 R+Q1 DR+
31 L  X+Q2
32 CR  Y+Q1 R+Q1 DR+
33 L  X+0
34 DEP LCT  X+0  Y+0 R4
35 CALL LBL 1 REPQ12
36 L  Z+200 R0 FMAX M30
37 END PGM Parametrica-Asola MM 
la seconda con salti di condizioni (vedi fine progr.. un po piu macchinosa..)

Codice: Seleziona tutto

 0  BEGIN PGM PARAM-ASOLA MM 
1  BLK FORM 0.1 Z  X-100  Y-100  Z-40
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  FN 0: Q1 =+20 ;(mezza-Y-(Raggio Asola))
4  FN 0: Q2 =+60 ;(mezza-X-(-raggio Asola))
5  FN 0: Q3 =+38 ;(profondita-totale)
6  FN 0: Q4 =+2 ;(incremento Z(divisibile con Q3)
7  TOOL CALL 16 Z S1500 F200
8  ; PUNTA per PREFORO centro asola
9  CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+1    ;BEZUGSPUNKT-NUMMER
10 CYCL DEF 7.0 NULLPUNKT
11 CYCL DEF 7.1  X+0
12 CYCL DEF 7.2  Y+0
13 CYCL DEF 7.3  Z+0
14 CYCL DEF 10.0 DREHUNG
15 CYCL DEF 10.1  ROT+45
16 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-45   ;TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN
17 L  X+0  Y+0  Z+5 R0 FMAX M13
18 CYCL CALL
19 L  Z+200 R0 FMAX M9
20 TOOL CALL 12 Z S5500 F1000
21 ;RICHIAMO utensile x lavorazione asola
22 L  X+0  Y+0  Z+5 R0 FMAX M13
23 L  Z+0 F AUTO
24 FN 0: Q5 =+0 ;INIZIO-CONTATORE Z
25 Q5 = Q5 - - Q4 ;sottrazione a Z
26 LBL 1
27 L  Z-Q5
28 APPR LCT  X+0  Y+Q1 R4 RL F AUTO
29 L  X-Q2
30 CR  Y-Q1 R+Q1 DR+
31 L  X+Q2
32 CR  Y+Q1 R+Q1 DR+
33 L  X+0
34 DEP LCT  X+0  Y+0 R4
35 Q5 = Q5 - - Q4;sottrazione a Z
36 FN 12: IF +Q5 LT +Q3 GOTO LBL 1
37 FN 9: IF +Q5 EQU +Q3 GOTO LBL 1
38 FN 11: IF +Q5 GT +Q3 GOTO LBL 99
39 LBL 99
40 L  Z+200 R0 FMAX M30
41 END PGM PARAM-ASOLA MM 
 
saluti luigi
Non hai i permessi necessari per visualizzare i file e le foto allegati in questo messaggio. Per visualizzare tali file devi registrarti ed effettuare il Login

Avatar utente
leomonti
Senior
Senior
Messaggi: 1744
Iscritto il: mercoledì 20 dicembre 2006, 19:04
Località: Bologna

Re: [richiesta] Programmino Asola

Messaggio da leomonti » giovedì 19 aprile 2018, 13:57

Chissà se nel tuo immenso archivio ne esista una versione anche per Colibri..... :D
Il cervello è l'organo più sopravvalutato...(W.Allen)

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » giovedì 19 aprile 2018, 14:24

Leo....certamente , ne ho sia a discesa ad elix che a passate asola interna oppure chiavetta esterna..

Avatar utente
leomonti
Senior
Senior
Messaggi: 1744
Iscritto il: mercoledì 20 dicembre 2006, 19:04
Località: Bologna

Re: [richiesta] Programmino Asola

Messaggio da leomonti » giovedì 19 aprile 2018, 16:03

Se hai voglia di condividerle, avrai sempre la mia personale (e quella di tutti gli utilizzatori di Colibri) eterna gratitudine :D
Il cervello è l'organo più sopravvalutato...(W.Allen)

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » giovedì 19 aprile 2018, 17:03

..postero a tempo sulla sezione adeguata Twintec alcuni programmi parametrici (inclusi quelli che intendi)
..a parte che i programmi girano anche su Mach ed anche RosettaCnc (che e` col RS 274 NGC identica al colibri)

Avatar utente
Amrik
Newbie
Newbie
Messaggi: 42
Iscritto il: giovedì 19 ottobre 2017, 23:27
Località: cremona

Re: [richiesta] Programmino Asola

Messaggio da Amrik » giovedì 19 aprile 2018, 19:03

Sei una persona molto altruista. :mrgreen:

Meno male che ci sono ancora persone come te! Che danno un aiuto agli altri senza ricevere niente in cambio.
Grazie per la cosa più preziosa che uno possa dare, Il suo TEMPO. =D> =D>
Immagine

Avatar utente
Amrik
Newbie
Newbie
Messaggi: 42
Iscritto il: giovedì 19 ottobre 2017, 23:27
Località: cremona

Re: [richiesta] Programmino Asola

Messaggio da Amrik » venerdì 20 aprile 2018, 20:06

Rieccomi,
@Gino
ho provato a scrivere il suo programma in macchina con il controllo vecchio (tnc 426/430), nel primo esempio che mi ha fatto quando vado ad iserire

Codice: Seleziona tutto

CALL LBL 1 REPQ12
non mi fa inserire il parametro Q nelle repitizioni del LBL, potrebbe essere un limite del controllo? :oops:








Nel secondo esempio riscontro un errore quando vado ad iserire la seguente formula:

Codice: Seleziona tutto

 Q5 = Q5 - - Q4;sottrazione a Z
Dopo aver digitato Q5= Q5 - .... non mi fa aggiungere il secondo segno.... nemme il parametro Q4 in negativo :cry: .


che delusione .... Secondo Lei sbaglio qualcosa?? (ho provato con il simulatore sul PC e non ho riscontrato problemi)
Immagine

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » venerdì 20 aprile 2018, 20:28

nel primo caso non so se dipende dal controllo..
nel secondo caso la cosa e` al 100% fattibile
seguente procedura : premi quando serve il tasto Q , la grafica apre sotto una finestra
li scegli FORMULE apre unaltra e scegli il segno " - "
poi dopo finito di scrivere quel che serve se devi aggiungere un "-" premi ancora il tasto +- della tastiera Heidenhain
Non hai i permessi necessari per visualizzare i file e le foto allegati in questo messaggio. Per visualizzare tali file devi registrarti ed effettuare il Login

Avatar utente
Amrik
Newbie
Newbie
Messaggi: 42
Iscritto il: giovedì 19 ottobre 2017, 23:27
Località: cremona

Re: [richiesta] Programmino Asola

Messaggio da Amrik » sabato 21 aprile 2018, 10:29

Probabilmente seguivo la stessa procedura fino ad inserimento del primo segno dopodiché provavo a inserire +/- senza prima definire l'altro valore a destra. Lunedì riprovo a fare il prog. in macchina.
Se ho capito bene

Codice: Seleziona tutto

Q1="Q2"(parametro) "-"(differenza) "-Q3"(valore  parametro con segno negativo)
Immagine

gino
Senior
Senior
Messaggi: 1770
Iscritto il: domenica 11 ottobre 2009, 18:12

Re: [richiesta] Programmino Asola

Messaggio da gino » sabato 21 aprile 2018, 11:06

..spiegazione dei salti condizionati..evidenzio in rosso.
....
20 TOOL CALL 12 Z S5500 F1000
21 ;RICHIAMO utensile x lavorazione asola
22 L X+0 Y+0 Z+5 R0 FMAX M13
23 L Z+0 F AUTO
24 FN 0: Q5 =+0 ;INIZIO-CONTATORE Z
25 Q5 = Q5 - - Q4 ;sottrazione a Z
26 LBL 1
27 L Z-Q5
28 APPR LCT X+0 Y+Q1 R4 RL F AUTO
29 L X-Q2
30 CR Y-Q1 R+Q1 DR+
31 L X+Q2
32 CR Y+Q1 R+Q1 DR+
33 L X+0
34 DEP LCT X+0 Y+0 R4
35 Q5 = Q5 - - Q4;sottrazione a Z
36 FN 12: IF +Q5 LT +Q3 GOTO LBL 1 ;verifica se Q5 e piu piccolo di Q3 ;torna inizio label
37 FN 9: IF +Q5 EQU +Q3 GOTO LBL 1 ;verifica se Q5 e uguale a Q3 ;torna inizio label
38 FN 11: IF +Q5 GT +Q3 GOTO LBL 99 ;verifica se Q5 e maggiore a Q3 ;salta a label 99 (fine programma)

39 LBL 99
40 L Z+200 R0 FMAX M30
41 END PGM PARAM-ASOLA MM

Avatar utente
nl2000sy
Member
Member
Messaggi: 240
Iscritto il: mercoledì 22 luglio 2015, 9:19
Località: Treviso

Re: [richiesta] Programmino Asola

Messaggio da nl2000sy » sabato 21 aprile 2018, 11:41

Un'idea...
Caricare il programma di Gino direttamente in macchina con TNCremo.
Se poi il TNC ti rileva un errore nella riga te lo segnala scrivendo ERROR all'inizio del blocco, almeno sai se è un problema di compatibilità, poi usi il copia/incolla se non sei in grado di scrivere il comando.

Avatar utente
leomonti
Senior
Senior
Messaggi: 1744
Iscritto il: mercoledì 20 dicembre 2006, 19:04
Località: Bologna

Re: [richiesta] Programmino Asola

Messaggio da leomonti » sabato 21 aprile 2018, 13:39

Sottoscrivo in pieno le considerazioni sull'altruismo di Gino. Raramente ho trovato persone così disponibili nel mettere a disposizione un notevolissimo bagaglio di conoscenze come il suo. E mai un accento saccente.
Il cervello è l'organo più sopravvalutato...(W.Allen)

Rispondi

Torna a “Heidenhain”