Link al Video: https://youtu.be/jLi80gQ7Vcs
Materiale: FE 520
Bloccaggio utensile: Mandrino idraulico Schunk ISO 40
Utensile: Fresa in metallo duro YG1 per finitura ø 12/Z6 lunghezza tagliente 50 mm.
Profondità cava 44 mm., eseguita in una sola passata.
Giri= S 2500
Passo fresatura= 0.8 mm.
Avanzamento lineare: F 1250
N° pezzi eseguiti: 56
Criterio di sostituzione utensile: nessuno, ho finito i pezzi
Tempo ciclo al pezzo: 2 minuti.
Metto anche il programma.
Codice: Seleziona tutto
0 BEGIN PGM ARPIONE-C MM
1 BLK FORM 0.1 Z X-20 Y-16 Z-90
2 BLK FORM 0.2 X+20 Y+16 Z+0
3 ;
4 ;PRESET=144-145-146
5 ;
6 ;ZERO=X-Y CENTRO PZ.-Z MAX
7 ;
8 TOOL CALL 11 Z S2500 ;HM.12/Z6-XL=50
9 TOOL DEF 14
10 ;
11 ;AV. LINEARE=F1250
12 ;AV. AL CENTRO=F730
13 ;
14 CYCL DEF 14.0 PROFILO
15 CYCL DEF 14.1 LABEL PROFILO11
16 ;
17 CYCL DEF 275 FR. TROC. SCAN. PROF ~
Q215=+1 ;TIPO LAVORAZIONE ~
Q219=+19 ;LARG. SCANALATURA ~
Q368=+0 ;QUOTA LATERALE CONS. ~
Q436=+0.8 ;AVANZ. AL GIRO ~
Q207=+730 ;AVANZAM. FRESATURA ~
Q351=+1 ;MODO FRESATURA ~
Q201=-43.8 ;PROFONDITA ~
Q202=+43.8 ;PROF. INCREMENTO ~
Q206=+10000 ;AVANZ. INCREMENTO ~
Q338=+0 ;INCREMENTO FINITURA ~
Q385=+450 ;AVANZAMENTO FINITURA ~
Q200=+3 ;DISTANZA SICUREZZA ~
Q203=+0 ;COORD. SUPERFICIE ~
Q204=+50 ;2. DIST. SICUREZZA ~
Q366=+0 ;PENETRAZIONE
18 ;
19 CALL LBL 10
20 L X+30 Y+0 Z+50 R0 FMAX M79 M3
21 CALL LBL 1
22 CALL LBL 20
23 CALL LBL 1
/ 24 CALL LBL 30
/ 25 CALL LBL 1
26 L Z+100 R0 FMAX M78 M5
27 M1
28 TOOL CALL 14 Z S2500 DR-0.005 ;HM.12/Z6-XL=50-FIN.
29 TOOL DEF 11
30 CALL LBL 10
31 L X+30 Y+0 Z+50 R0 FMAX M79 M3
32 CALL LBL 2
33 CALL LBL 20
34 CALL LBL 2
/ 35 CALL LBL 30
/ 36 CALL LBL 2
37 L Z+100 R0 FMAX M78 M5
38 L X+500 Y+0 Z-20.91 R0 FMAX M91
39 STOP M2
40 LBL 1 ;SGR.CAVA
41 L X+30 Y+0 R0 FMAX
42 L Z+3 R0 FMAX M99
43 LBL 0
44 LBL 2 ;FIN.CAVA
45 L X+30 Y+0 R0 FMAX
46 L Z+3 R0 FMAX
47 L Y+9.57 Z-44 RL FMAX
48 L X-30 F1200
49 L Y+0 R0 FMAX
50 L Y-9.57 RL FMAX
51 L X+30
52 L Y+0 R0 FMAX
53 ;
54 L Y-9.6 RR FMAX
55 L X-30 F900
56 L Y+0 R0 FMAX
57 L Y+9.6 RR FMAX
58 L X+30
59 L Y+0 R0 FMAX
60 L Z+50 R0 FMAX
61 LBL 0
62 LBL 11 ;PROFILO CAVA
63 APPR LCT Y+0 R2 RL
64 L X-27
65 LBL 0
66 ;
67 LBL 10
68 CYCL DEF 247 DEF. ZERO PEZZO ~
Q339=+144 ;NUMERO ORIGINE
69 LBL 0
70 LBL 20
71 CYCL DEF 247 DEF. ZERO PEZZO ~
Q339=+145 ;NUMERO ORIGINE
72 LBL 0
73 LBL 30
74 CYCL DEF 247 DEF. ZERO PEZZO ~
Q339=+146 ;NUMERO ORIGINE
75 LBL 0
76 END PGM ARPIONE-C MM