Funzionerà? Cerco aiuto per macro ATC con Mach3. Si inizia..

[pierpaolo]

Esattamentissimamente QUELLO!!!

Niente in più niente in meno!!
Secondo te Pedro, si riuscirebbe a mettere una sorta di messaggio come nella prima macro di esempio che allegavo, che se si mette un numero di utensile in più o in meno della portata del carosello, ti dia la possibilità di correggerlo? Nn so messaggio del tipo "errore attivazione sensore braccio fuori" ecc ecc??

Cmq si, il video dimostra con estrema esattezza il funzionamento!!

[Pedro]

ho scritto mezza macro...se ce la faccio finisco stasera se no la finirò domani. Non è facile se non si può provare, ma vabbè; diciamo che è in corso d'opera

[pierpaolo]

UN GRAZIE DA PARTE DI TUTTI PER L'IMPEGNO.... MA SOPRATTUTTO DI CUORE DA PARTE MIA....

[Pedro]

si, si ringrazia vedrai quando dovrai raccogliere tutti gli utensili da terra che sono stati catapultati via

dai scherzo...è divertente ma sarebbe bene poi provarla funzionante sulla macchina

[Pedro]

ecco la prima stesura: diciamo che è proprio la prima prima, devo rileggerla ma credo che di massima sia così

ci sono molte cose da affinare come la frenatura del mandrino e le posizioni degli utensili rispetto allo zero dell'asse B, bisogna montarlo e prima di provarlo, come dicevo prima, bisogna provare una funzione alla volta...ma visto che volevi la macro



' Macro cambio utensile automatico (ATC) Rel 1.01 del 14/10/2013

'**************** Definizione degli I/O (si considerano attivi ad 1 e disattivi a 0(

' Output 1 comando carosello fuori
' Input 1 sensore carosello fuori
' Output 2 comando carosello dentro
' Input 2 sensore carosello dentro
' Output 3 pinza mandrino
' Output 4 valvola aria pulizia mandrino
' Home B sensore di zero su carosello
' Output 5 freno mandrino
' Input 4 sensore di posizione mandrino

'*************** Definizione variabili

Dim old_tool As Single 'N. Utensile nel mandrino; 0 siginifica vuoto
Dim new_tool As Single 'N utensile da prelevare, numeri ammessi da 1 a 8
Dim B_pos (8) As Double ' sono le posizioni, in gradi, degli utensili messi sul carosello
Dim refrigerante As Single ' memorizza se si stava usando il refrigerante o no
Dim old_speed As Single ' memorizza la velocità del mandrino


'************** Definizione costanti

Const safe_z=-11 'posizione z sicura per il carosello
Const load_z = -44 'posizione z per presa utensile
Const timeout_carosello=10 'quanto tempo può impiegare il carosello per uscire o rientrare prima di errore
Const Z_speed=30 'velocità di movimento asse Z
Const B_speed=30 'velocità movimento carosello

' le posizioni degli utensili nel carosello. Non si è usata una formula in modo da poter tarare esattamente ogni posizione

B_pos(1)=0
B_pos(2)=45
B_pos(3)=90
B_pos(4)=135
B_pos(5)=180
B_pos(6)=45
B_pos(7)=270
B_pos(8)=315




' **** Inizio Programma ****
old_speed=GetRPM() 'legge la velocità mandrino

' controlla se esiste lo zero macchina per assi Z e B

If GetOEMLed(809)=0 Or GetOEMLed(811)=0 Then 'manca lo Zero macchina su Z o lo zero sul carosello
MachMsg("NON E'STATO FATTO LO ZERO MACCHINA","ERRORE",0) ' scrive messaggio di errore

Code("M5 M9") 'ferma il refrigerante e ferma il mandrino
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If

' ferma refrigerante e ferma mandrino
refrigerante= GetOemLed(13) 'se stavo usando il refrigerante o no
Code("M9") 'ferma il refrigerante
Code("S20") 'rallenta il mandrino
While(IsACTIVE(Input 4)=0) 'attende l'index posizione mandrino
Wend
Code "M5"
ActivateSignal(Output 5) 'attiva freno mandrino su inverter
sleep(1000) 'applica freno per 1 secondo
DeactivateSignal(Output 5) 'toglie il freno

old_tool = GetCurrentTool()
new_tool = GetSelectedTool()
If(new_tool>8) ' se il sensore del carosello fuori non è attivo
MachMsg("Il numero consentito di utensili è tra 1 e 8","ERRORE",0) ' scrive messaggio di errore
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If

If(old_tool>0) Then 'al primo cambio utensili mi trovo il mandrino vuoto altrimenti devo rimettere l'utensile a posto

' *********** Rimette l'utensile dentro il carosello

' porta z nella posizione LOAD per uscita carosello utensili e rimettere l'utensiel a posto


Code "G53" 'passa a coordinate assolute macchina
Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
Code "G01 Z" & load_z 'porta Z nella posizione LOAD per far uscire il carosello e rimettere l'utensile dentro
While IsMoving() ' attendi fino a che si ferma
Wend
Code "F" & B_speed
Code "G01 B" & B_pos(old_tool)
While IsMoving() ' attendi fino a che si ferma
Wend

' porta fuori il carosello

ActivateSignal(Output 1) 'sposta il carosello in fuori
sleep(timeout_carosello * 1000) ' attende che il carosello sia fuori
If(IsACTIVE(Input 1)=0) ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output 2) 'riporta il carosello dentro
wait(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output 2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If
ActivateSignal(Output 3) 'apre la pinza del mandrino per mollare l'utensile
wait(1000) 'aspetta un secondo
ActivateSignal(Output 4) 'flush aria compressa per pulizia
wait(500) 'aspetta mezzo secondo
DeActivateSignal(Output 4) 'ferma flush aria compressa per pulizia
End If

' *********** Va a prendere il nuovo utensile

Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
DeActivateSignal(Output 3) 'chiude la pinza del mandrino
Code "G01 Z" & safe_z 'porta Z nella posizione Safe per far ruotare il carosello
While IsMoving() ' attendi fino a che si ferma
Wend
Code "F" & B_speed
Code "G01 B" & B_pos(new_tool) 'si posiziona sul nuovo utensile
While IsMoving() ' attendi fino a che si ferma
Wend


' porta fuori il carosello

ActivateSignal(Output 1) 'sposta il carosello in fuori
sleep(timeout_carosello * 1000) ' attende che il carosello sia fuori
If(IsACTIVE(Input 1)=0) ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output 2) 'riporta il carosello dentro
wait(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output 2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If


Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
ActivateSignal(Output 3) 'apre la pinza del mandrino
Code "G01 Z" & load_z 'porta Z nella posizione di presa
While IsMoving() ' attendi fino a che si ferma
Wend
ActivateSignal(Output 3) 'chiude la pinza del mandrino
sleep(1000) 'attendi 1 secondo
ActivateSignal(Output 2) 'riporta il carosello dentro
wait(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output 2)

If(IsACTIVE(Input 2)=0) ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output 2) 'riporta il carosello dentro
wait(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output 2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If


Code "G54" 'passa a coordinate precedenti
Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
Code "G01 Z" GetToolchangestart(2) 'rimette Z dove era prima della macro
While IsMoving() ' attendi fino a che si ferma
Wend
If refrigerante Then
Code "M7" 'se il refrigerante era acceso lo rimette
End If

END

[Pedro]

poi con calma metto le spiegazioni, la correggo semmai trovassi errori (l'ho scritta di getto). Non si legge bene così messa nel forum perchè non fa l'indent delle funzioni e non abilita la tabulazione. Se apri il file zippato o con l'editor di mach3 o con wordpad si legge meglio

[pierpaolo]

È proprio il caso di dire.... SEI GRANDE PEDRO...

Leggendola così mi sembra quasi utopia ma se funziona sei davvero un drago... Ora mi sto intanto, scervellando con quella c...o di interfaccia usb che sembra far funzionare tutti i led ma mach3 nelle impostazioni riconosce solo l'input del pin 1.... Maledetti aggeggi cinesi....

Cmq grazie davvero per il tempo che ci stai impegnando

[pierpaolo]

Mi sovviene una domanda Pedro,

Ma se io a inizio lavoro ho sempre il mandrino scarico, come faccio a fargli prendere il primo utensile utile dal carosello??
Forse devo mettere un comando M6 all'inizio di ogni gcode?

In più mi sembrava di vedere dalla macro che il mandrino e il refrigerante si disattivano prima di arrivare ad alzare tutti gli assi in posizione di cambio... Forse lo sto leggendo con troppa foga per la contentezza.... Dai la rileggerò con più attenzione e calma....

[Pedro]

molto brevemente

il mandrino deve essere per forza scarico quando si entra in mach3 se no non sa che utensile ha, di default mach3 all'accensione dovrebbe avere zero come tool. In tutte le lavorazioni successive si sa come nel corso della singola lavorazione.

Si presume che l'M6 sia generato da un cam e tutti i cam che ho ed ho usato, se ben programmati, dicono che utensile prendere prima di lavorare, sempre...anche il primo, sempre. Se non lo dicono...si sta sbagliando cam.

Se invece vuoi fare una cosa diciamo alla svelta, a mano o quasi allora infili quel che vuoi e fai quel che vuoi però non avendo sensore degli utensili nel carosello, te lo chiesi, non puoi aspettarti che rimetta il coso a posto, non sa cosa è.

Fermare il refrigerante? si, se no magari fa il lago sul carosello, fermare il mandrino... meglio che lo tiro su di un po' se no rimane piantato..devo fare quella modifica, in effetti anche qualcun altra ma ripeto, siamo alla prima stesura. Appena avrò un po' di tempo provvedo

[pierpaolo]

Hai ragione.... Si hai proprio ragione.... Uso rhinocam e fa proprio quello che dici mi sembra... Poi cmq stasera controllo se nel gcode c'è fin da subito la riga M6....

Hai ragione per quanto riguarda il lago sul carosello!! Vedi! come sempre è un piacere leggerti.....

[marco 83]

Se non mi sbaglio per quanto riguarda l utensile inserito nel mandrino c'è da fleggare nella pagina configurazione generale persistant tool...o una cosa del genere in teoria mach si ricorda l ultimo utensile caricato....

[Pedro]

si, si è vero ma poco cambia, se non parte con il tool=0 va rimettere quello che sta nel mandrino al posto del tool che c'era prima dell'esecuzione della macro ...

e fin qui tutto ok solo che non sappiamo a priori se mach3 si era chiuso in modo corretto, l'unico modo con cui salva i parametri "persistant". Non so, è un po' una incognita secondo me, forse no...valutate come meglio volete

[Pedro]

sviste e riviste

come sempre i programmi vanno poi riletti: alcuni errori di sintassi corretti e tolte alcune subs che volevo all'inizio fare ma che poi ho eliminato ed anche spostato la sequenza di fermo mandrino dopo averlo, giustamente, alzato. Ci sono alcune cose che ancora non mi convincono molto ed appena ho altri 5 minuti le rivedrò



' Macro cambio utensile automatico (ATC) Rel 1.02 del 15/10/2013

'**************** Definizione degli I/O (si considerano attivi ad 1 e disattivi a 0(

' Output 1 comando carosello fuori
' Input 1 sensore carosello fuori
' Output 2 comando carosello dentro
' Input 2 sensore carosello dentro
' Output 3 pinza mandrino
' Output 4 valvola aria pulizia mandrino
' Home B sensore di zero su carosello
' Output 5 freno mandrino
' Input 4 sensore di posizione mandrino

'*************** Definizione variabili

Dim old_tool As Single 'N. Utensile nel mandrino; 0 siginifica vuoto
Dim new_tool As Single 'N utensile da prelevare, numeri ammessi da 1 a 8
Dim B_pos (8) As Double ' sono le posizioni, in gradi, degli utensili messi sul carosello
Dim refrigerante As Single ' memorizza se si stava usando il refrigerante o no
Dim old_speed As Single ' memorizza la velocità del mandrino
Dim counter As Double 'yimeout fermo mandrino


'************** Definizione costanti

Const safe_z=-11 'posizione z sicura per il carosello
Const load_z = -44 'posizione z per presa utensile
Const timeout_carosello=10 'quanto tempo può impiegare il carosello per uscire o rientrare prima di errore
Const Z_speed=30 'velocità di movimento asse Z
Const B_speed=30 'velocità movimento carosello
' le posizioni degli utensili nel carosello. Non si è usata una formula in modo da poter tarare esattamente ogni posizione

B_pos(1)=0
B_pos(2)=45
B_pos(3)=90
B_pos(4)=135
B_pos(5)=180
B_pos(6)=45
B_pos(7)=270
B_pos(8)=315




' **** Inizio Programma ****
old_speed=GetRPM() 'legge la velocità mandrino

' controlla se esiste lo zero macchina per assi Z e B

If GetOEMLed(809)=0 Or GetOEMLed(811)=0 Then 'manca lo Zero macchina su Z o lo zero sul carosello
MachMsg("NON E'STATO FATTO LO ZERO MACCHINA","ERRORE",0) ' scrive messaggio di errore

Code("M5 M9") 'ferma il refrigerante e ferma il mandrino
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If

' ferma refrigerante e ferma mandrino
refrigerante= GetOemLed(13) 'se stavo usando il refrigerante o no
Code("M9") 'ferma il refrigerante
Code "G53" 'passa a coordinate assolute macchina
Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
Code "G01 Z" & load_z 'porta Z nella posizione LOAD per far uscire il carosello e rimettere l'utensile dentro
While IsMoving() ' attendi fino a che si ferma
Wend
Code("S20") 'rallenta il mandrino
counter=300000
While(IsACTIVE(Input4)=0 Or counter > 0) 'attende l'index posizione mandrino o timeout
couter=counter-1
Wend
sleep (500) 'leggero ritardo
If (IsActive(INPUT4)=0) Then ' se il sensore del carosello fuori non è attivo
MachMsg("Il mandrino non si è fermato correttamente","ERRORE",0) ' scrive messaggio di errore
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If
Code "M5"
ActivateSignal(Output5) 'attiva freno mandrino su inverter
sleep(1000) 'applica freno per 1 secondo
DeactivateSignal(Output5) 'toglie il freno

old_tool = GetCurrentTool()
new_tool = GetSelectedTool()
If(new_tool>8) Then ' se il sensore del carosello fuori non è attivo
MachMsg("Il numero consentito di utensili è tra 1 e 8","ERRORE",0) ' scrive messaggio di errore
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If

If(old_tool>0) Then 'al primo cambio utensili mi trovo il mandrino vuoto altrimenti devo rimettere l'utensile a posto

' *********** Rimette l'utensile dentro il carosello

' rimettere l'utensiel a posto


Code "F" & B_speed
Code "G01 B" & B_pos(old_tool)
While IsMoving() ' attendi fino a che si ferma
Wend

' porta fuori il carosello

ActivateSignal(Output1) 'sposta il carosello in fuori
sleep(timeout_carosello * 1000) ' attende che il carosello sia fuori
If(IsACTIVE(Input1)=0) Then ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output2) 'riporta il carosello dentro
sleep(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If
ActivateSignal(Output3) 'apre la pinza del mandrino per mollare l'utensile
sleep(1000) 'aspetta un secondo
ActivateSignal(Output4) 'flush aria compressa per pulizia
sleep(500) 'aspetta mezzo secondo
DeActivateSignal(Output4) 'ferma flush aria compressa per pulizia
End If

' *********** Va a prendere il nuovo utensile

Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
DeActivateSignal(Output3) 'chiude la pinza del mandrino
Code "G01 Z" & safe_z 'porta Z nella posizione Safe per far ruotare il carosello
While IsMoving() ' attendi fino a che si ferma
Wend
Code "F" & B_speed
Code "G01 B" & B_pos(new_tool) 'si posiziona sul nuovo utensile
While IsMoving() ' attendi fino a che si ferma
Wend


' porta fuori il carosello

ActivateSignal(Output1) 'sposta il carosello in fuori
sleep(timeout_carosello * 1000) ' attende che il carosello sia fuori
If(IsACTIVE(Input1)=0) then ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output2) 'riporta il carosello dentro
sleep(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If


Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
ActivateSignal(Output3) 'apre la pinza del mandrino
Code "G01 Z" & load_z 'porta Z nella posizione di presa
While IsMoving() ' attendi fino a che si ferma
Wend
ActivateSignal(Output3) 'chiude la pinza del mandrino
sleep(1000) 'attendi 1 secondo
ActivateSignal(Output2) 'riporta il carosello dentro
sleep(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output2)

If(IsACTIVE(Input2)=0) Then ' se il sensore del carosello fuori non è attivo
MachMsg("IL CAROSELLO E' BLOCCATO","ERRORE",0) ' scrive messaggio di errore
ActivateSignal(Output2) 'riporta il carosello dentro
sleep(timeout_carosello*1000) 'aspetta
DeactivateSignal(Output2)
DoOEMButton(1003) 'ferma l'esecuzione del gcode
End 'esce dalla macro
End If


Code "G54" 'passa a coordinate precedenti
Code "F" & Z_speed 'porta la velocità di Z a quella impostata per ATC
Code "G01 Z" & GetToolchangestart(2) 'rimette Z dove era prima della macro
While IsMoving() ' attendi fino a che si ferma
Wend
If refrigerante Then
Code "M7" 'se il refrigerante era acceso lo rimette
End If

END

[pierpaolo]

Ti seguo come penso ti stiano seguendo tutti

[Pedro]

il fatto è che è molto personalizzata 'sta cosa. Comunque può una volta messo a punto il tutto facilmente essere traslata su un sistema a carosello analogo. Trovassi il modo di fissare un mandrino MT2 sulla mia macchina un carosello così me lo costruirei